#!/bin/csh

#######################################################################################################################################
#                                                                                                                                     #
#         C O N S T R U C T I O N   D ' U N   C A R R E L A G E   P A R                                                               #
#         D U P L I C A T I O N   D ' U N   M O R C E A U   D ' I M A G E                                                             #
#         E T   A V E C   S Y M E T R I S A T I O N   A   L ' I N T E R I E U R                                                       #
#         D ' U N   E L E M E N T   D U   C A R R E L A G E  :                                                                        #
#                                                                                                                                     #
#                                                                                                                                     #
#         Utilisation :                                                                                                               #
#                                                                                                                                     #
#                   $xci/carrelage.02$Z <imageA> <imageR> <NbandeV> <NbandeH>                                                         #
#                                                                                                                                     #
#                                                                                                                                     #
#         Author of '$xci/carrelage.02$Z' :                                                                                           #
#                                                                                                                                     #
#                     Jean-Francois Colonna (LACTAMME, AAAAMMJJhhmmss).                                                               #
#                                                                                                                                     #
#######################################################################################################################################

set       imageA=$1
set       imageR=$2

set       NbandeV=$3
set       NbandeH=$4

setArgum  NbandeV                       1
                                        # Nombre de bandes Verticales a priori...                                                     #

setArgum  NbandeH                       1
                                        # Nombre de bandes Herticales a priori...                                                     #

@         SNbandeV = 2 * $NbandeV
@         SNbandeV = $SNbandeV + 1
@         SNbandeH = 2 * $NbandeH
@         SNbandeH = $SNbandeH + 1

FileTmpB            nomT
                                        # Creation d'un nom temporaire...                                                             #

$xci/init$X         niveau=$NOIR R=$nomT                                                                                $formatI
                                        # Initialisation de l'image Resultat.                                                         #

set       LtranslationHA=`$xci/valeurs_inte$X premiere=1 derniere=$SNbandeV vD=1.0 vA=0.0 cubique=FAUX`
set       LtranslationHR=`$xci/valeurs_inte$X premiere=1 derniere=$SNbandeV vD=0.0 vA=1.0 cubique=FAUX`
                                        # Definition de la liste des translations Horizontales necessaires a obtenir les bandes       #
                                        # Verticales desirees...                                                                      #
$xci/move$X         fond=FAUX         A=$imageA xA=$LtranslationHA[2]                                                   $formatI  |     \
$xci/move$X         fond=VRAI F=$imageA         xR=$LtranslationHR[2] R=$nomT                                           $formatI
                                        # Symetrisation d'axe Vertical a l'interieur d'une bande verticale.                           #

set       LtranslationVA=`$xci/valeurs_inte$X premiere=1 derniere=$SNbandeH vD=1.0 vA=0.0 cubique=FAUX`
set       LtranslationVR=`$xci/valeurs_inte$X premiere=1 derniere=$SNbandeH vD=0.0 vA=1.0 cubique=FAUX`
                                        # Definition de la liste des translations Verticales necessaires a obtenir les bandes         #
                                        # Verticales desirees...                                                                      #
$xci/move$X         fond=FAUX         A=$nomT   yA=$LtranslationVA[2]                                                   $formatI  |     \
$xci/move$X         fond=VRAI F=$nomT           yR=$LtranslationVR[2] R=$nomT                                           $formatI
                                        # Symetrisation d'axe Horizontal a l'interieur d'une bande horizontale.                       #

$xci/carrelage.01$Z $nomT $imageR $NbandeV $NbandeH
                                        # Et generation des bandes symetriques...                                                     #

FileTmpE            nomT
                                        # Puis destruction de l'image temporaire...                                                   #