#!/bin/csh

#######################################################################################################################################
#                                                                                                                                     #
#         E X T R A C T I O N   D ' U N E   S E Q U E N C E   C O N T E N U E   D A N S   U N   F I C H I E R  :                      #
#                                                                                                                                     #
#                                                                                                                                     #
#         Utilisation :                                                                                                               #
#                                                                                                                                     #
#                   $xci/Fsequence$Z    <fichier> <racine_des_images> <premiere> <derniere> <pas>                                     #
#                                                                                                                                     #
#                                                                                                                                     #
#                   ATTENTION : il faut donner en general des paths complets !!!                                                      #
#                                                                                                                                     #
#                                                                                                                                     #
#         Author of '$xci/Fsequence$Z' :                                                                                              #
#                                                                                                                                     #
#                     Jean-Francois Colonna (LACTAMME, AAAAMMJJhhmmss).                                                               #
#                                                                                                                                     #
#######################################################################################################################################

set  file=$1
set  racine=$2
set  premiere=$3
set  derniere=$4
set  pas=$5

if   ("$pas" == "$K_VIDE") then
     set  Pas=1
else
     set  Pas=$pas
endif

SIZE $file
set  SfileA=$Fsize
                                        # Taille relle du fichier argument.                                                           #
SIZE $xiio/NOIR
set  Simage=$Fsize
                                        # Taille d'une image "standard".                                                              #
@    SfileB = $derniere - $premiere
@    SfileB = $SfileB + 1
@    SfileB = $SfileB * $Pas
@    SfileB = $SfileB * $Simage
                                        # Taille minimale du fichier argument pour contenir les images demandees.                     #
if   ($SfileA >= $SfileB) then
     set  liste=`$xci/nombres$X A=$K_VIDE premiere=$premiere derniere=$derniere pas=$Pas`
                                        # Generation de la liste des numeros d'images Resultat.                                       #
     foreach   n         ($liste)
          $xci/acces$X A="$fichier $file $n" R=$racine$n $formatI
                                        # Recuperation des images une a une.                                                          #
     end
else
     EROR "Le fichier argument est trop petit pour contenir autant d'images."
endif